Exploring Eye Exposure to Laser Radiation at Distance

NOTE: This document is a work in progress. Please email any comments or corrections to the address at the bottom of this document.
WARNING: Do not use this document as a guide for the determination of safe levels of laser exposure. 

News accounts of laser pointers being pointed at aircraft have given rise to concerns about the safety of these devices, particularly some of the high powered devices that are being sold. This demonstration explores the possible exposure that might occur to the retina in the case of an exposure at distances on the order of thousands of meters.

Lasers have a divergence that yields a beam diameter at a given distance. The power transmitted through an aperture smaller than the beam diameter is approximately the total power at distance multiplied by the ratio of the aperture area to the total area of the incident beam. If the aperture is the pupil of an eye the incident beam will be focused to a spot on the retina. The power transmitted through the pupil divided by the spot area determines the exposure plotted below in Watts/(cm^2).

Needs["Units`"]

Ratio of circular areas:

areaRatio[d1_,d2_] := (((((d1/2)))^2)/((((d2/2)))^2))

Area for a given diameter in meters:

area[diameter_] := π ((((diameter/2)Meter))^2)

Beam diameter at distance (ref. Photon Inc. Application Note 220):

diameter[waist_, distance_,divergence_] := (Sqrt[(waist^2) + (divergence^2) (distance^2)])

Fraction of power transmitted through the pupil at distance:

pupilPower[rating_,distance_,divergence_,pupilDiameter_,waist_] := Watt rating areaRatio[pupilDiameter,diameter[waist,distance,divergence]];

Spot size of beam of pupil width (Need citation for this calculation of spot size on retina. In Laser Safety (Henderson and Schulmeister) there is a reference to 1.5 milliradian being the smallest spot size that can be achieved which should correlate to ca. .017 mm.)

spotSize[eyeFocalLength_,λ_,pupilDiameter_] := 2.44 ((eyeFocalLength λ)/pupilDiameter) ;

Calculate exposure in Watts per square Meter given rating in milliwatts, distance in meters, divergence in milliradians, pupilDiameter in millimeters, eyeFocalLength in millimeters, laser wavelength λ in nanometers, beam waist in millimeters:

exposure[rating_,distance_,divergence_,pupilDiameter_,eyeFocalLength_,λ_,waist_] := pupilPower[rating 10^-3,distance,divergence 10^-3,pupilDiameter 10^-3,waist 10^-3] /area[spotSize[eyeFocalLength 10^-3,λ 10^-9,pupilDiameter 10^-3]];

Plot retinal exposure for a range of laser powers and distances as Watts per (cm^2) which intersects a plane of maximum exposure. Parameters may be set via the sliders.

Manipulate[Show[Plot3D[Convert[exposure[rating,d,divergence,pupilDia,17,λ,waist],Watt/Centimeter^2] Centimeter^2/Watt,{rating,5,500},{d,minDistance,maxDistance},ColorFunction->(Hue[1 ]&),PlotLabel->"Retinal Exposure W/(cm^2)",AxesLabel->{"Rating (mW)","Distance (m)"}],Plot3D[maxExposure,{rating,5,500},{d,minDistance,maxDistance},ColorFunction->(Hue[.7]&)]],
{{divergence,.52,"Divergence (milliradians)"},.1,2,Appearance->"Labeled"},{{minDistance,1000,"Min Distance (meters)"},100,1000,Appearance->"Labeled"},{{maxDistance,10000,"Max distance (meters)"},1000,10000,1000,Appearance->"Labeled"},{{waist,3,"beam waist (millimeters)"},1,10,1,Appearance->"Labeled"},{{pupilDia,7,"pupil diameter (millimeters)"},1,8,1,Appearance->"Labeled"},{{λ,530,"Wavelength (nanometers)"},400,900,10,Appearance ->"Labeled"},{{maxExposure,16,"maximum exposure (W/(cm^2))"},1,100,1,Appearance ->"Labeled"},
SaveDefinitions->True]

Thank You

Thank you for viewing this demonstration. Did you find it useful? Do you have a suggestion for a correction or other improvement? Please contact us at analyst@10squaredcorp.com and let us know.